NEW!Mosquitto で MQTT 双方向通信　(5)IoT デバイス ソフトウエアコード

// MQTT_VPS_CPP
// MQTT over TLS

#include <Arduino.h>
#include <WiFi.h>
#include <PubSubClient.h>
#include <WiFiClientSecure.h>

//端子定義
#define state_pin19 19      //入力端子
#define output_on_pin21 21  //出力端子
#define output_off_pin2 2   //出力端子

//時刻表示用
#define JST     3600* 9
struct tm timeInfo; //時刻を格納するオブジェクト
char s[20];         //文字格納用

//状態変化検出用 
bool state_pin = false;
bool state_pin_pre = false;

//ループ実行周期設定用
unsigned long old = 0;       // 前回実行時刻を初期化
unsigned long interval = 10; // 実行周期を設定 10ms

// WiFi 認証情報
const char *ssid = "wifi_ssid";
const char *password = "wifi_password";

// MQTT Broker settings
const char *mqtt_broker = "domain-name";
const char *mqtt_topic = "MQTT topic";
const char *mqtt_username = "username";
const char *mqtt_password = "password";
const int mqtt_port = 8883;
bool option_retain = false;

// WiFi and MQTT client initialization
WiFiClientSecure esp_client;
PubSubClient mqtt_client(esp_client);

// Letsencript で生成した CA 証明書 ISRG_Root_X1.pem
const char* ca_cert= \
"-----BEGIN CERTIFICATE-----\n" \
"MIIFazCCA1OgAwIBAgIRAIIQz7DSQONZRGPgu2OCiwAwDQYJKoZIhvcNAQELBQAw\n" \
"TzELMAkGA1UEBhMCVVMxKTAnBgNVBAoTIEludGVybmV0IFNlY3VyaXR5IFJlc2Vh\n" \
"cmNoIEdyb3VwMRUwEwYDVQQDEwxJU1JHIFJvb3QgWDEwHhcNMTUwNjA0MTEwNDM4\n" \
"WhcNMzUwNjA0MTEwNDM4WjBPMQswCQYDVQQGEwJVUzEpMCcGA1UEChMgSW50ZXJu\n" \
"ZXQgU2VjdXJpdHkgUmVzZWFyY2ggR3JvdXAxFTATBgNVBAMTDElTUkcgUm9vdCBY\n" \
"MTCCA
"h77ct
"0TM8u
"A5/TR
"T8KOE
"B5T0Y
"B5iPN
"KBds0
"OlFuh
"jh8BC
"qHyGO
"rU7m2
"HRMBA
"hkiG9
"ubhzE
"3BebY
"NFtY2
"ORAzI
"TkXWS
"jNPElpzVmbUq4JUagEiuTDkHzsxHpFKVK7q4+63SM1N95R1NbdWhscdCb+ZAJzVc\n" \
"oyi3B43njTOQ5yOf+1CceWxG1bQVs5ZufpsMljq4Ui0/1lvh+wjChP4kqKOJ2qxq\n" \
"4RgqsahDYVvTH9w7jXbyLeiNdd8XM2w9U/t7y0Ff/9yi0GE44Za4rF2LN9d11TPA\n" \
"mRGunUHBcnWEvgJBQl9nJEiU0Zsnvgc/ubhPgXRR4Xq37Z0j4r7g1SgEEzwxA57d\n" \
"emyPxgcYxn/eR44/KJ4EBs+lVDR3veyJm+kXQ99b21/+jh5Xos1AnX5iItreGCc=" \
"-----END CERTIFICATE-----\n";

//---------------- Function Declarations プロトタイプ宣言 -------------------------------------//
std::string get_time_info();
void connectToWiFi();
void connectToMQTT();
void mqttCallback(char *topic, byte *payload, unsigned int length);

//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++//
//+                                   setup                                                     +//
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++//

void setup() {
    //端子設定
    pinMode(state_pin19, INPUT_PULLDOWN);
    pinMode(output_on_pin21, OUTPUT);
    pinMode(output_off_pin2, OUTPUT);
    digitalWrite(output_on_pin21, LOW);
    digitalWrite(output_off_pin2, LOW);
    //シリアル通信開始
    Serial.begin(115200);
    //ターミナルにメッセージ出力
    Serial.print("\nESP32 ⇔ MQTT Broker 間通信");
    Serial.print("\n通信プロトコル： MQTT over TLS");
    //WiFi 接続の関数呼び出し
    connectToWiFi();
    //NTPの設定
    configTime(9 * 3600L, 0, "ntp.nict.jp", "time.google.com", "ntp.jst.mfeed.ad.jp");
    //MQTT通信用設定
    esp_client.setCACert(ca_cert); // Set Root CA certificate
    mqtt_client.setServer(mqtt_broker, mqtt_port);
    mqtt_client.setKeepAlive(60);
    mqtt_client.setCallback(mqttCallback);
    //MQTT接続する関数呼び出し
    connectToMQTT();
}
//++++++++++++++++++++++++++++++++++ ここまで setup  +++++++++++++++++++++++++++++++++++++++++//

//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++//
//+                                   loop                                                  +//
//+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++//

void loop(){
    unsigned long curr = millis(); // 現在時刻を取得
    if ((curr - old) >= interval) {
        // do periodic tasks // interval = 10ms 毎に実行する     
        //19pin の状態を state_pin に代入する
        state_pin = digitalRead(state_pin19);
        //state_pin が変化した場合 にパブリッシュする
        if (state_pin != state_pin_pre){
            //文字列 str_state に端子が HIGH か LOW_ かの状態を設定する
            std::string str_state;
            if(digitalRead(state_pin19)==HIGH){
                str_state="HIGH";
            }else{
                str_state ="LOW_";
            }
            //現在時刻と端子の状態から publish する文字列を生成する     
            std::string buf1 = get_time_info();
            buf1 ="{\"date\":\"" + buf1 + "\",\"client\":\"ESP32__\",\"state\":\"" + str_state + "\",\"control\":\"NULL_\"}";
            //publish message upon connection
            mqtt_client.publish(mqtt_topic, buf1.c_str(), option_retain);
            Serial.print("\npublish selected at loop\n");
            Serial.print(buf1.c_str());
            Serial.println("\nEnd_of_Publish_+++++++++++++++++++++++++++++++++++++++++++++++++\n");
            state_pin_pre = state_pin;
        }
        mqtt_client.loop(); 
        old = curr;                  // 前回実行時刻を現在時刻で更新
    }
}
//+++++++++++++++++++++++++++++++++++ ここまで loop ++++++++++++++++++++++++++++++++++++++++++++//

//---------------- ここから  -----------------------------------------------------------//
 //現在時刻を取得して char s[] に設定する
std::string get_time_info(){
    //tmオブジェクトのtimeInfoに現在時刻を入れ込む
    getLocalTime(&timeInfo);
    //人間が読める形式に変換
    sprintf(s, "%04d-%02d-%02dT%02d:%02d:%02d.000",
    timeInfo.tm_year + 1900, timeInfo.tm_mon + 1, timeInfo.tm_mday,
    timeInfo.tm_hour, timeInfo.tm_min, timeInfo.tm_sec);
    delay(100);
    //文字列に変換
    std::string buf10 = s;
    return buf10;
}

//---------------- ここから WiFi 接続 -----------------------------------------------------------//

void connectToWiFi() {
    WiFi.begin(ssid, password);
    Serial.print("\nConnecting to WiFi\n");
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }
    Serial.println("\nConnected to WiFi");
    
    //モニターにローカル IPアドレスを表示する
    Serial.println("WiFi connected.");
    Serial.print("  *IP address: ");
    Serial.println(WiFi.localIP());
}

//---------------- ここから MQTT 接続 ------------------------------------------------------------//

void connectToMQTT() {
    //MAC uint_8t*
    while (!mqtt_client.connected()) {
        // ESP32 の macAddress からユニークな client_id を生成
        std::string bufx = std::string(WiFi.macAddress().begin(), WiFi.macAddress().end());
        std::string client_id = "esp32-client-" + bufx ;
        Serial.printf("Connecting to MQTT Broker as %s...\n", client_id.c_str());
        if (mqtt_client.connect(client_id.c_str(), mqtt_username, mqtt_password)) {
            Serial.println("Connected to MQTT broker");
            mqtt_client.subscribe(mqtt_topic);
            Serial.println("\nsubscribe started at setup");     
        } else {
            Serial.print("Failed to connect to MQTT broker, rc=");
            Serial.print(mqtt_client.state());
            Serial.println(" Retrying in 5 seconds.");
            delay(5000);
        }
    }
}

//---------------- ここから MQTT コールバック ----------------------------------------------------//

void mqttCallback(char *topic, byte *payload, unsigned int length) {
    Serial.print("Message received on topic: ");
    Serial.println(topic);
    std::string buf2 = "" ; 

    //payload 全体を取得してターミナルに出力
    for (unsigned int i = 0; i < length; i++) {
        Serial.print((char) payload[i]);
        buf2= buf2+ (char)payload[i];
    }
    
    //payload から control 値を抽出
    std::string buf3 = "" ; 
    for (unsigned int i = 79; i < 83; i++) {
        buf3= buf3+ (char)payload[i];
    }
    //Serial.print("\nbuf3=");
    //Serial.print(buf3.c_str());

    //control 値に応じて出力端子を制御
    if (buf3 =="ON__"){
        digitalWrite(output_on_pin21, HIGH);
        digitalWrite(output_off_pin2, LOW);
          Serial.print("\nON___pin21=HIGH");
    }else if(buf3=="OFF_"){
        digitalWrite(output_on_pin21, LOW);
        digitalWrite(output_off_pin2, HIGH);
          Serial.print("\nOFF__pin2=HIGH");
    }
    Serial.println("\nEnd_of_mqttCallback---------------------------------------------\n");
}
//---------------- ここまで MQTT コールバック -----------------------------------------------------//